Wikipédia:Wikidata-segítségkérés/Lekérdezések Wikidata karbantartáshoz
Ezen a lapon olyan lekérdezéseket gyűjtünk, amelyek a Wikidata - elsősorban magyar vonatkozású - elemeinek karbantartását segíthetik.
Javaslat új lekérdezés hozzáadásához
- a szakaszcím rövid legyen, de azért derüljön ki belőle, hogy miket lehet kilistázni a lekérdezéssel
- írd le folyószöveggel, hogy mire szolgál a lekérdezés, hogy olyasvalaki is megértse, aki nem tud SPARQL lekérdezésből "olvasni"
- utalj arra, hogy mekkora nagyságrendű munkáról van szó, esetleg írd bele - dátummal -, hogy hány elemet listáz a lekérdezés a beírás pillanatában
- ha a lekérdezés apró módosítással más témában is hasznos, írd bele, hogy mit mire kell javítani, hogy a másik témában is használni lehessen
- magát a lekérdezést a
{{SPARQL}}sablonba burkolva add meg, és lehetőleg tedd dobozba, hogy ne foglaljon el túl sok helyet
Személyek extrém hiányos Wikidata elemei[szerkesztés]
- 2020 december 11.: kb. 200
- 2021. március 20.: 122
- 2021. augusztus 24.: 42
Ezzel a lekérdezéssel azok a Wikidata-elemek listázhatók, amelyekhez csatolva van magyar szócikk, de csak egy tulajdonság van bennük megadva, vagyis jelentős kiegészítésre szorulnak. Ha olyan elemekre vagy kíváncsi, amiken csak 2 (vagy három stb.) tulajdonság van megadva, akkor a statement sorban kell átírni az 1-est 2-esre (3-asra stb.) így:
wikibase:statements 1
helyett:
wikibase:statements 3
| Személyek extrém hiányos Wikidata elemei |
|---|
SELECT ?item ?article ?title
WHERE
{
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
?item wdt:P31 wd:Q5.
?article schema:about ?item ;
schema:isPartOf <https://hu.wikipedia.org/> .
?article schema:name ?title .
?item wikibase:sitelinks 1;
wikibase:statements 2
}
|
Általában elmondható, hogy egy ismert életutú személyhez 10 tulajdonság felvihető, ahol ennél kevesebb van, azt érdemes átnézni.
Magyar szócikkek extrém hiányos Wikidata elemei[szerkesztés]
Erre a linkre kattintva azok a Wikidata elemek, és magyar Wikipédia szócikkek listázódnak ki, amelyekben a Wikidatán egyetlen adat sincs megadva: nem lehet tudni, hogy egy iskola vagy egy betegség, egy költő, vagy egy település eleméről van szó. Palotabarát vita 2021. december 12., 13:25 (CET)
Neveléstudósok, akik lehet, hogy pedagógusok[szerkesztés]
- 2020 nyara: 300
- 2021. augusztus 24.: 250
Egy fordítás javítása miatt a korábban "pedagógus" értelemben használt foglalkozás elem (a d:Q1231865) neveléstudós lett. Azok a magyar pedagógusok (középiskolai tanárok, tanítók, egyetemi oktatók), akiknél a foglalkozás (P106) tulajdonsághoz ez lett megadva, hirtelen neveléstudóssá váltak. Az alábbi lista tételeit egyenként ellenőrizni kell, és ahol szükséges, ott javítani. Ugyanakkor vannak ténylege neveléstudósként dolgozó személyek, tehát nem szabad automatikusan javítani, az életrajz függvényében vagy át kell írni ezt az adatot, vagy nem.
| Neveléstudósok, akik lehet, hogy pedagógusok |
|---|
SELECT ?item ?itemLabel ?szul WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
?item wdt:P106 wd:Q1231865;
wdt:P27 wd:Q28.
OPTIONAL { ?item wdt:P569 ?szul. }
}
|
Magyar nyelvű címke nélküli foglalkozásnevek[szerkesztés]
- 2021. augusztus 24: 6552 db.
Az alanti lekérdezés megmutatja azokat a foglalkozásokat, amelyeknek nincs magyar címkéjük. Sorba lehet rendezni aszerint, hogy hány nyelven van hozzá szócikk csatolva - ez mutatja, hogy mennyire kurrens foglalkozásról van szó. Fontos, hogy ha beírtok egy magyar címkét, keressetek is rá egy másik fülön ugyanarra, mert lehet, hogy más elemen már használatban van. Ennek az lehet az oka, hogy
- a másikat rosszul fordították, akkor az javítandó
- te fordítottad rosszul, a másik a jó: ekkor gondold át mégegyszer
- duplikátumról van szó (ez elég ritka)
- hasonló szakmákról van szó, csak más országokban többet vagy kevesebbet jelent az általunk ismert magyar kifejezés; ekkor nagy segítség a leírásban megmagyarázni miről van szó (pl.: ügyvéd, tanár stb.)
- nem kell mindent lefordítani, egy csomó "szakma" van, aminek nincs is magyar megfelelője, előfordul, hogy csak magyar átírása van (pl. távol-keleti szerzetesek megnevezései, történelmi szakmák, titulusok stb.)
Hasznos segítség lehet a mai egyetemi képzési leírások az egyetemek honlapjain, ahol gyakran megadják a szakirány nevét angolul is.
| Magyar nyelvű címke nélküli foglalkozásnevek |
|---|
SELECT ?item ?itemLabel ?sl WHERE {
#Az ezt követő sor végén lehet módosítani a kiírás nyelvét. Jelenleg angol, francia, német
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,fr,de". }
?item wdt:P31 wd:Q28640.
MINUS { ?item rdfs:label ?hulabel FILTER ( lang(?hulabel) = "hu" ) }
OPTIONAL {?item wikibase:sitelinks ?sl } BIND(xsd:integer(BOUND(?sl) && ?sl > 0) as ?p9)
}
|
A lekérdezés harmadik sorának a végefelé (pirossal) láttok nyelvkódokat: ha ezek helyett annak a nyelvnek a kódját adjátok meg, ami nektek könnyebben megy, csak azon a nyelven adja ki a leírást (persze, csak ha bele van írva az elembe). Most angol (en), francia (fr), német (de) nyelven listáz. Például ha az orosz leírással szeretnétek listázni, akkor ez a sor így néz ki:
SERVICE wikibase:label { bd:serviceParam wikibase:language "ru". }
de számítani kell arra, hogy oroszul kevesebb címke van megadva, mint mondjuk angolul.
Magyar nyelvű Wikipédia-cikkek angol címke nélküli elemei[szerkesztés]
- 2020-ban kb. 5000
- 2021. augusztus 24-én 2191 db
Nagyon sok, a magyar Wikipédián szócikkel rendelkező személy Wikidata eleméhez nincs megadva angol leírás. Zömüknek sajnos a Wikidata adatlapja is rém hiányos, szinte semmi nem derül ki belőle, egy magyarul nem beszélő szerkesztő nem is tudja pótolni az angol leírást, vagyis ennek rendezése a mi feladatunk, mert csak mi értjük, hogy a szócikk kiről és miről szól. (Sokszor egyébként maga a szócikk is necces, gyakori a duplum Wd-elem, csak nem tudjuk párosítani annyira hiányos, vagy éppen gyanúsan nem nevezetes, szóval néha elég kínlódós feladat).
| Magyar nyelvű Wikipédia-cikkek angol címke nélküli elemei |
|---|
SELECT ?item ?itemLabel
WHERE
{
# hint:Query hint:optimizer "None".
?item wikibase:sitelinks 1 .
[] schema:about ?item ; schema:isPartOf <https://hu.wikipedia.org/> .
?item wdt:P31 wd:Q5 .
MINUS { ?item rdfs:label ?l . FILTER ( lang(?l) = "en") }
SERVICE wikibase:label { bd:serviceParam wikibase:language "hu". }
}
|